VB .NET Authentication Program Example

Create a new class library project and you might want to use AuthenticateVB as the solution and project names.

Imports System

Imports System.Net

Imports System.Text

Imports System.IO

Imports System.Collections

Public Class AuthenticateClassSample

    ' Displays simple usage information for running the sample.       

    Shared Sub usage()

        Console.WriteLine("usage: Executable_file_name [-r URI] [-u user-name] [-p password] [-d domain]")

        Console.WriteLine("Available options:")

        Console.WriteLine("     -r  URI         URI resource to retrieve")

        Console.WriteLine("     -u  user-name   Username to use for authentication")

        Console.WriteLine("     -p  password    Password to use for authentication")

        Console.WriteLine("     -d  domain      Domain to use for authentication")

        Console.WriteLine("     -m              Displays authentication modules")

        Console.WriteLine()

    End Sub

    ' Retrieves the specified URI with the given credential information. The retrieved resource

    ' is simply printed to the Console.

    Shared Sub RetrieveUri(ByVal uriName As String, ByVal creds As NetworkCredential)

        Dim httpRequest As HttpWebRequest = Nothing

        Dim httpResponse As HttpWebResponse = Nothing

        Try

            httpRequest = CType(WebRequest.Create(uriName), HttpWebRequest)

            Console.WriteLine("Creating web request...")

            httpRequest.Credentials = creds

            httpResponse = CType(httpRequest.GetResponse(), HttpWebResponse)

            Dim httpReader As StreamReader = New StreamReader(httpResponse.GetResponseStream(), Encoding.UTF8)

            Dim httpContent As String = httpReader.ReadToEnd()

            Console.WriteLine(httpContent)

            httpReader.Close()

        Catch wex As WebException

            Console.WriteLine("Exception occurred: {0}", wex.Message)

            Console.WriteLine(wex.StackTrace)

            httpResponse = CType(wex.Response, HttpWebResponse)

        Finally

            If (Not IsNothing(httpResponse)) Then

                httpResponse.Close()

            End If

        End Try

    End Sub

    ' Enumerates and prints the available authentication modules.

    Shared Sub DisplayAuthenticationModules()

        Dim registeredModules As IEnumerator = AuthenticationManager.RegisteredModules

        Console.WriteLine("Authentication Modules:")

        While (registeredModules.MoveNext())

            Dim currentAuthenticationModule As IAuthenticationModule = CType(registeredModules.Current, IAuthenticationModule)

            Console.WriteLine("   Module : {0}", registeredModules.Current)

            Console.WriteLine("    Supports Pre-Authentication : {0}", currentAuthenticationModule.CanPreAuthenticate)

        End While

    End Sub

    ' This routine parses the command line, creates the user credential object if

    ' credentials are supplied and issues the request.

    Shared Sub Main()

        Dim userCredentials As NetworkCredential = Nothing

        Dim uriResource As String = "https://www.cert.org"

        Dim userName As String = "anonymous"

        Dim passWord As String = "test@yahoo.com"

        Dim domain As String = Nothing

        ' Parse the command line

        Dim args As String() = Environment.GetCommandLineArgs()

        Dim i As Integer

        usage()

        For i = 1 To args.GetUpperBound(0)

            Try

                Dim CurArg() As Char = args(i).ToCharArray(0, args(i).Length)

                If (CurArg(0) = "-") Or (CurArg(0) = "/") Then

                    Select Case Char.ToLower(CurArg(1), System.Globalization.CultureInfo.CurrentCulture)

                        Case "d"

                            ' Domain to use for authentication

                            i = i + 1

                            domain = args(i)

                        Case "m"

                            ' Display registered authentication modules

                            DisplayAuthenticationModules()

                        Case "p"

                            ' Password to use for authentication

                            i = i + 1

                            passWord = args(i)

                        Case "r"

                            ' URI resource to download (get)

                            i = i + 1

                            uriResource = args(i)

                        Case "u"

                            ' Username to use for authentication

                            i = i + 1

                            userName = args(i)

                        Case "x"

                            ' Web proxy to use for all requests

                            i = i + 1

                            WebRequest.DefaultWebProxy = New WebProxy(args(i))

                        Case Else

                            usage()

                            Exit Sub

                    End Select

                End If

            Catch e As Exception

                usage()

                Exit Sub

            End Try

        Next

        ' Make the request

        Console.WriteLine("Make the request...")

        Try

            If ((Not userName Is Nothing) Or (Not passWord Is Nothing) Or (Not domain Is Nothing)) Then

                userCredentials = New NetworkCredential(userName, passWord, domain)

            End If

            RetrieveUri(uriResource, userCredentials)

        Catch ex As Exception

            Console.WriteLine("Exception occurred: {0}", ex.Message)

            Console.WriteLine(ex.StackTrace)

        End Try

    End Sub

End Class